Input Parameters

H :

A symmetric matrix of doubles, representing the Hessian of the quadratic problem.

f :

A vector of doubles, representing coefficients of the linear terms in the quadratic problem.

A :

A matrix of doubles, containing the coefficients of linear inequality constraints of size (m X n) where 'm' is the number of linear inequality constraints.

b :

A vector of doubles, related to 'A' and containing the the Right hand side equation of the linear inequality constraints of size (m X 1).

Aeq :

A matrix of doubles, containing the coefficients of linear equality constraints of size (m1 X n) where 'm1' is the number of linear equality constraints.

beq :

A vector of doubles, related to 'Aeq' and containing the the Right hand side equation of the linear equality constraints of size (m1 X 1).

lb :

A vector of doubles, containing the lower bounds of the variables of size (1 X n) or (n X 1) where 'n' is the number of variables.

ub :

A vector of doubles, containing the upper bounds of the variables of size (1 X n) or (n X 1) where 'n' is the number of variables.

x0 :

A vector of doubles, containing the starting values of variables of size (1 X n) or (n X 1) where 'n' is the number of variables.

param :

A list, containing the option for user to specify. See below for details.

Outputs

xopt :

A vector of doubles, containing the computed solution of the optimization problem.

fopt :

A double, containing the value of the function at xopt.

exitflag :

An integer, containing the flag which denotes the reason for termination of algorithm. See below for details.

output :

A structure, containing the information about the optimization. See below for details.

lambda :

A structure, containing the Lagrange multipliers of the lower bounds, upper bounds and constraints at the optimized point. See below for details.

Description

Search the minimum of a constrained linear quadratic optimization problem specified by :

quadprogmat calls BONMIN, an optimization library written in C++, to solve the optimization problem.

Options

The options allow the user to set various parameters of the Optimization problem. The syntax for the options is given by:

options= list("MaxIter", [---], "CpuTime", [---], "GradObj", ---, "Hessian", ---, "GradCon", ---);

The options should be defined as type "list" and consist of the following fields:

• MaxIter : A Scalar, specifying the maximum number of iterations that the solver should take.
• CpuTime : A Scalar, specifying the maximum amount of CPU time in seconds that the solver should take.

The default values for the various items are given as:

options = list("MaxIter", [3000], "CpuTime", [600]);

The exitflag allows the user to know the status of the optimization which is returned by BONMIN. The values it can take and what they indicate is described below:

• 0 : Optimal Solution Found
• 1 : Maximum Number of Iterations Exceeded. Output may not be optimal.
• 2 : Maximum amount of CPU Time exceeded. Output may not be optimal.
• 3 : Stop at Tiny Step.
• 4 : Solved To Acceptable Level.
• 5 : Converged to a point of local infeasibility.

For more details on exitflag, see the BONMIN documentation which can be found on https://www.coin-or.org/Bonmin/Doxygen/html/

The output data structure contains detailed information about the optimization process. It is of type "struct" and contains the following fields.

• output.iterations: The number of iterations performed.
• output.constrviolation: The max-norm of the constraint violation.

The lambda data structure contains the Lagrange multipliers at the end of optimization. In the current version, the values are returned only when the the solution is optimal. It has type "struct" and contains the following fields.

• lambda.lower: The Lagrange multipliers for the lower bound constraints.
• lambda.upper: The Lagrange multipliers for the upper bound constraints.
• lambda.eqlin: The Lagrange multipliers for the linear equality constraints.
• lambda.ineqlin: The Lagrange multipliers for the linear inequality constraints.

Example

Here we solve a simple objective function.

Find x in R^6 such that it minimizes:

//Example 1:
//Minimize 0.5*x'*H*x + f'*x with
f=[1; 2; 3; 4; 5; 6]; H=eye(6,6);
[xopt,fopt,exitflag,output,lambda]=quadprogmat(H,f)

Example

//Example 2:
f=[1; 2; 3; 4; 5; 6]; H=eye(6,6);
//Inequality constraints
A= [0,1,0,1,2,-1;
-1,0,2,1,1,0];
b = [-1; 2.5];
[xopt,fopt,exitflag,output,lambda]=quadprogmat(H,f,A,b)

Example

//Example 3:
//Minimize 0.5*x'*H*x + f'*x with
f=[1; 2; 3; 4; 5; 6]; H=eye(6,6); 
//Inequality constraints
A= [0,1,0,1,2,-1;
-1,0,2,1,1,0];
b = [-1; 2.5];
//Equality constraints
Aeq= [1,-1,1,0,3,1;
-1,0,-3,-4,5,6;
2,5,3,0,1,0];
beq=[1; 2; 3];
[xopt,fopt,exitflag,output,lambda]=quadprogmat(H,f,A,b,Aeq,beq)

Example

In this example, we proceed to add the upper and lower bounds to the objective function.

//Example 4:
//Minimize 0.5*x'*H*x + f'*x with
f=[1; 2; 3; 4; 5; 6]; H=eye(6,6);
//Inequality constraints
A= [0,1,0,1,2,-1;
-1,0,2,1,1,0];
b = [-1; 2.5];
//Equality constraints
Aeq= [1,-1,1,0,3,1;
-1,0,-3,-4,5,6;
2,5,3,0,1,0];
beq=[1; 2; 3];
//Variable bounds
lb=[-1000; -10000; 0; -1000; -1000; -1000];
ub=[10000; 100; 1.5; 100; 100; 1000];
[xopt,fopt,exitflag,output,lambda]=quadprogmat(H,f,A,b,Aeq,beq,lb,ub)

Example

In this example, we initialize the values of x to speed up the computation. We further enhance the functionality of quadprogmat by setting input options.

//Example 5:
//Minimize 0.5*x'*H*x + f'*x with
f=[1; 2; 3; 4; 5; 6]; H=eye(6,6);
//Inequality constraints
A= [0,1,0,1,2,-1;
-1,0,2,1,1,0];
b = [-1; 2.5];
//Equality constraints
Aeq= [1,-1,1,0,3,1;
-1,0,-3,-4,5,6;
2,5,3,0,1,0];
beq=[1; 2; 3];
//Variable bounds
lb=[-1000; -10000; 0; -1000; -1000; -1000];
ub=[10000; 100; 1.5; 100; 100; 1000];
//Initial guess and options
x0 = repmat(0,6,1);
options = list("MaxIter", 300, "CpuTime", 100);
[xopt,fopt,exitflag,output,lambda]=quadprogmat(H,f,A,b,Aeq,beq,lb,ub,x0,options)

Example

//Example 6:
//Minimize 0.5*x'*H*x + f'*x with
f=[1; 2; 3; 4; 5; 6]; H=eye(6,6);
//Inequality constraints
A= [0,1,0,1,2,-1;
-1,0,2,1,1,0];
b = [-1; 2.5];
//Equality constraints
Aeq= [0,1,0,1,2,-1;
-1,0,-3,-4,5,6];
beq=[4; 2];
[xopt,fopt,exitflag,output,lambda]=quadprogmat(H,f,A,b,Aeq,beq)

Example

Unbounded Problems: Find x in R^6 such that it minimizes the objective function used above under the following constraints:

//Example 7:
//Minimize 0.5*x'*H*x + f'*x with
f=[1; 2; 3; 4; 5; 6]; H=eye(6,6); H(1,1) = -1;
//Inequality constraints
A= [0,1,0,1,2,-1;
-1,0,2,1,1,0];
b = [-1; 2.5];
//Equality constraints
Aeq= [1,-1,1,0,3,1;
-1,0,-3,-4,5,6];
beq=[1; 2];
[xopt,fopt,exitflag,output,lambda]=quadprogmat(H,f,A,b,Aeq,beq)

Authors

• Keyur Joshi, Saikiran, Iswarya, Harpreet Singh