fminimax

Solves a minimax optimization problem.

Calling Sequence

xopt = fminimax(fun,x0)
xopt = fminimax(fun,x0,A,b)
xopt = fminimax(fun,x0,A,b,Aeq,beq)
xopt = fminimax(fun,x0,A,b,Aeq,beq,lb,ub)
xopt = fminimax(fun,x0,A,b,Aeq,beq,lb,ub,nonlinfun)
xopt = fminimax(fun,x0,A,b,Aeq,beq,lb,ub,nonlinfun,options)
[xopt, fval] = fminimax(.....)
[xopt, fval, maxfval]= fminimax(.....)
[xopt, fval, maxfval, exitflag]= fminimax(.....)
[xopt, fval, maxfval, exitflag, output]= fminimax(.....)
[xopt, fval, maxfval, exitflag, output, lambda]= fminimax(.....)

Input Parameters

fun:: The function to be minimized. fun is a function that has a vector x as an input argument, and contains the objective functions evaluated at x.
x0 :: A vector of doubles, containing the starting values of variables of size (1 X n) or (n X 1) where 'n' is the number of Variables.
A :: A matrix of doubles, containing the coefficients of linear inequality constraints of size (m X n) where 'm' is the number of linear inequality constraints.
b :: A vector of doubles, related to 'A' and represents the linear coefficients in the linear inequality constraints of size (m X 1).
Aeq :: A matrix of doubles, containing the coefficients of linear equality constraints of size (m1 X n) where 'm1' is the number of linear equality constraints.
beq :: A vector of double, vector of doubles, related to 'Aeq' and represents the linear coefficients in the equality constraints of size (m1 X 1).
lb :: A vector of doubles, containing the lower bounds of the variables of size (1 X n) or (n X 1) where 'n' is the number of variables.
ub :: A vector of doubles, containing the upper bounds of the variables of size (1 X n) or (n X 1) where 'n' is the number of variables.
nonlinfun:: A function, representing the nonlinear Constraints functions(both Equality and Inequality) of the problem. It is declared in such a way that nonlinear inequality constraints (c), and the nonlinear equality constraints (ceq) are defined as separate single row vectors.
options :: A list, containing the option for user to specify. See below for details.

Outputs

xopt :: A vector of doubles, containing the computed solution of the optimization problem.
fval :: A vector of doubles, containing the values of the objective functions at the end of the optimization problem.
maxfval:: A double, representing the maximum value in the vector fval.
exitflag :: An integer, containing the flag which denotes the reason for termination of algorithm. See below for details.
output :: A structure, containing the information about the optimization. See below for details.
lambda :: A structure, containing the Lagrange multipliers of lower bound, upper bound and constraints at the optimized point. See below for details.

Description

fminimax minimizes the worst-case (largest) value of a set of multivariable functions, starting at an initial estimate, a problem generally referred to as the minimax problem.

Currently, fminimax calls fmincon which uses the Ipopt solver.

max-min problems can also be solved with fminimax, using the identity

Options

The options allow the user to set various parameters of the Optimization problem. The syntax for the options is given by:

options= list("MaxIter", [---], "CpuTime", [---], "GradObj", ---, "GradCon", ---);

MaxIter : A Scalar, specifying the Maximum Number of iterations that the solver should take.
CpuTime : A Scalar, specifying the Maximum amount of CPU Time in seconds that the solver should take.
GradObj : A function, representing the gradient function of the Objective in Vector Form.
GradCon : A function, representing the gradient of the nonlinear Constraints (both Equality and Inequality) of the problem. It is declared in such a way that gradient of nonlinear inequality constraints are defined first as a separate Matrix (cg of size m2 X n or as an empty), followed by gradient of nonlinear equality constraints as a separate matrix (ceqg of size m2 X n or as an empty) where m2 & m3 are number of nonlinear inequality and equality constraints respectively.
Default Values : options = list("MaxIter", [3000], "CpuTime", [600]);

The default values for the various items are given as:

options = list("MaxIter", [3000], "CpuTime", [600]);

The objective function must have a header :

F = fun(x)

where x is a n x 1 matrix of doubles and F is a m x 1 matrix of doubles where m is the total number of objective functions inside F. On input, the variable x contains the current point and, on output, the variable F must contain the objective function values.

By default, the gradient options for fminimax are turned off and and fmincon does the gradient opproximation of minmaxObjfun. In case the GradObj option is off and GradCon option is on, fminimax approximates minmaxObjfun gradient using the numderivative toolbox.

Syntax

Some syntactic details about fminimax, including the syntax for the gradient, defining the nonlinear constraints, and the constraint derivative function have been provided below:

If the user can provide exact gradients, it should be done, since it improves the convergence speed of the optimization algorithm.

Furthermore, we can enable the "GradObj" option with the statement :

minimaxOptions = list("GradObj",fGrad);

This will let fminimax know that the exact gradient of the objective function is known, so that it can change the calling sequence to the objective function. Note that, fGrad should be mentioned in the form of N x n where n is the number of variables, N is the number of functions in objective function.

The constraint function must have header:

[c, ceq] = confun(x)

Where x is a n x 1 matrix of minimax doubles, c is a 1 x nni matrix of doubles and ceq is a 1 x nne matrix of doubles (nni : number of nonlinear inequality constraints, nne : number of nonlinear equality constraints). On input, the variable x contains the current point and, on output, the variable c must contain the nonlinear inequality constraints and ceq must contain the nonlinear equality constraints.

By default, the gradient options for fminimax are turned off and and fmincon does the gradient opproximation of confun. In case the GradObj option is on and GradCons option is off, fminimax approximates confun gradient using numderivative toolbox.

If we can provide exact gradients, we should do so since it improves the convergence speed of the optimization algorithm.

Furthermore, we must enable the "GradCon" option with the statement :

minimaxOptions = list("GradCon",confunGrad);

This will let fminimax know that the exact gradient of the objective function is known, so that it can change the calling sequence to the objective function.

The constraint derivative function must have header :

[dc,dceq] = confungrad(x)

where dc is a nni x n matrix of doubles and dceq is a nne x n matrix of doubles.

The exitflag allows the user to know the status of the optimization which is returned by Ipopt. The values it can take and what they indicate is described below:

0 : Optimal Solution Found
1 : Maximum Number of Iterations Exceeded. Output may not be optimal.
2 : Maximum amount of CPU Time exceeded. Output may not be optimal.
3 : Stop at Tiny Step.
4 : Solved To Acceptable Level.
5 : Converged to a point of local infeasibility.

For more details on exitflag, see the ipopt documentation which can be found on http://www.coin-or.org/Ipopt/documentation/

The output data structure contains detailed information about the optimization process. It is of type "struct" and contains the following fields.

output.Iterations: The number of iterations performed.
output.Cpu_Time : The total cpu-time taken.
output.Objective_Evaluation: The number of Objective Evaluations performed.
output.Dual_Infeasibility : The Dual Infeasiblity of the final soution.
output.Message: The output message for the problem.

The lambda data structure contains the Lagrange multipliers at the end of optimization. In the current version the values are returned only when the the solution is optimal. It has type "struct" and contains the following fields.

lambda.lower: The Lagrange multipliers for the lower bound constraints.
lambda.upper: The Lagrange multipliers for the upper bound constraints.
lambda.eqlin: The Lagrange multipliers for the linear equality constraints.
lambda.ineqlin: The Lagrange multipliers for the linear inequality constraints.
lambda.eqnonlin: The Lagrange multipliers for the nonlinear equality constraints.
lambda.ineqnonlin: The Lagrange multipliers for the nonlinear inequality constraints.

A few examples displaying the various functionalities of fminimax have been provided below. You will find a series of problems and the appropriate code snippets to solve them.

Example

Here we solve a simple objective function, subjected to no constraints.

//Example 1:
// Objective function
function f=myfun(x)
f(1)= 2*x(1)^2 + x(2)^2 - 48*x(1) - 40*x(2) + 304;     //Objectives
f(2)= -x(1)^2 - 3*x(2)^2;
f(3)= x(1) + 3*x(2) -18;
f(4)= -x(1) - x(2);
f(5)= x(1) + x(2) - 8;
endfunction
// The initial guess
x0 = [0.1,0.1];
// Run fminimax
[x,fval,maxfval,exitflag,output,lambda] = fminimax(myfun, x0)

Example

We proceed to add simple linear inequality constraints.

//Example 2:
//Objective function
function f=myfun(x)
f(1)= 2*x(1)^2 + x(2)^2 - 48*x(1) - 40*x(2) + 304;     //Objectives
f(2)= -x(1)^2 - 3*x(2)^2;
f(3)= x(1) + 3*x(2) -18;
f(4)= -x(1) - x(2);
f(5)= x(1) + x(2) - 8;
endfunction
// The initial guess
x0 = [0.1,0.1];
//Linear Inequality constraints
A=[1,1 ; 1,1/4 ; 1,-1];
b=[2;1;1];
// Run fminimax
[x,fval,maxfval,exitflag,output,lambda] = fminimax(myfun, x0,A,b)

Example

Here we build up on the previous example by adding linear equality constraints. We add the following constraints to the problem specified above:

//Example 3:
//Objective function
function f=myfun(x)
f(1)= 2*x(1)^2 + x(2)^2 - 48*x(1) - 40*x(2) + 304;     //Objectives
f(2)= -x(1)^2 - 3*x(2)^2;
f(3)= x(1) + 3*x(2) -18;
f(4)= -x(1) - x(2);
f(5)= x(1) + x(2) - 8;
endfunction
// The initial guess
x0 = [0.1,0.1];
//Linear Inequality constraints
A=[1,1 ; 1,1/4 ; 1,-1];
b=[2;1;1];
//We specify the linear equality constraints below.
Aeq = [1,-1; 2, 1];
beq =  [1;2];
// Run fminimax
[x,fval,maxfval,exitflag,output,lambda] = fminimax(myfun, x0,A,b,Aeq,beq)

Example

In this example, we proceed to add the upper and lower bounds to the objective function.

//Example 4:
//Objective function
function f=myfun(x)
f(1)= 2*x(1)^2 + x(2)^2 - 48*x(1) - 40*x(2) + 304;     //Objectives
f(2)= -x(1)^2 - 3*x(2)^2;
f(3)= x(1) + 3*x(2) -18;
f(4)= -x(1) - x(2);
f(5)= x(1) + x(2) - 8;
endfunction
// The initial guess
x0 = [0.1,0.1];
//Linear Inequality constraints
A=[1,1 ; 1,1/4 ; 1,-1];
b=[2;1;1];
//We specify the linear equality constraints below.
Aeq = [1,-1; 2, 1];
beq =  [1;2];
//The upper and lower bounds for the objective function are defined in simple vectors as shown below.
lb = [-1;-%inf];
ub = [%inf;1];    //
// Run fminimax
[x,fval,maxfval,exitflag,output,lambda] = fminimax(myfun, x0,A,b,Aeq,beq,lb,ub)

Example

Finally, we add the nonlinear constraints to the problem. Note that there is a notable difference in the way this is done as compared to defining the linear constraints.

//Example 5:
//Objective function
function f=myfun(x)
f(1)= 2*x(1)^2 + x(2)^2 - 48*x(1) - 40*x(2) + 304;     //Objectives
f(2)= -x(1)^2 - 3*x(2)^2;
f(3)= x(1) + 3*x(2) -18;
f(4)= -x(1) - x(2);
f(5)= x(1) + x(2) - 8;
endfunction
// The initial guess
x0 = [0.1,0.1];
//Linear Inequality constraints
A=[1,1 ; 1,1/4 ; 1,-1];
b=[2;1;1];
//We specify the linear equality constraints below.
Aeq = [1,-1; 2, 1];
beq =  [1;2];
//The upper and lower bounds for the objective function are defined in simple vectors as shown below.
lb = [-1;-%inf];
ub = [%inf;1];    //
//Nonlinear constraints are required to be defined as a single function with the inequality and equality constraints in separate vectors.
function [c, ceq]=nlc(x)
c=[x(1)^2-1,x(1)^2+x(2)^2-1];
ceq=[];
endfunction
// Run fminimax
[x,fval,maxfval,exitflag,output,lambda] = fminimax(myfun, x0,A,b,Aeq,beq,lb,ub)

Example

We can further enhance the functionality of fminimax by setting input options. We can pre-define the gradient of the objective function and/or the hessian of the lagrange function and thereby improve the speed of computation. This is elaborated on in example 6. We take the following problem, specify the gradients, and the jacobian matrix of the constraints. We also set solver parameters using the options.

//Example 6: Using the available options
function f=myfun(x)
f(1)= 2*x(1)^2 + x(2)^2 - 48*x(1) - 40*x(2) + 304;
f(2)= -x(1)^2 - 3*x(2)^2;
f(3)= x(1) + 3*x(2) -18;
f(4)= -x(1) - x(2);
f(5)= x(1) + x(2) - 8;
endfunction

// Defining gradient of myfun
function G=myfungrad(x)
G = [ 4*x(1) - 48, -2*x(1), 1, -1, 1;
2*x(2) - 40, -6*x(2), 3, -1, 1; ]'
endfunction
// The nonlinear constraints and the Jacobian
// matrix of the constraints
function [c, ceq]=confun(x)
// Inequality constraints
c = [1.5 + x(1)*x(2) - x(1) - x(2), -x(1)*x(2) - 10]
// No nonlinear equality constraints
ceq=[]
endfunction
// Defining gradient of confungrad
function [DC, DCeq]=cgrad(x)
// DC(:,i) = gradient of the i-th constraint
// DC = [
//   Dc1/Dx1  Dc1/Dx2
//   Dc2/Dx1  Dc2/Dx2
//   ]
DC= [
x(2)-1, -x(2)
x(1)-1, -x(1)
]'
DCeq = []'
endfunction
// Test with both gradient of objective and gradient of constraints
minimaxOptions = list("MaxIter", [3000], "CpuTime", [600],"GradObj",myfungrad,"GradCon",cgrad);
// The initial guess
x0 = [0,10];
// The expected solution : only 4 digits are guaranteed
xopt = [0.92791 7.93551]
fopt = [6.73443  -189.778  6.73443  -8.86342  0.86342]
maxfopt = 6.73443
// Run fminimax
[x,fval,maxfval,exitflag,output] = fminimax(myfun,x0,[],[],[],[],[],[], confun, minimaxOptions)

Example

Infeasible Problems: Find x in R^2 such that it minimizes the objective function used above under the following constraints:

//Example 7:
//Objective function
function f=myfun(x)
f(1)= 2*x(1)^2 + x(2)^2 - 48*x(1) - 40*x(2) + 304;     //Objectives
f(2)= -x(1)^2 - 3*x(2)^2;
f(3)= x(1) + 3*x(2) -18;
f(4)= -x(1) - x(2);
f(5)= x(1) + x(2) - 8;
endfunction
// The initial guess
x0 = [0.1,0.1];
//Linear Inequality constraints
A=[1,1 ; 1,1/4 ; 1,-1];
b=[2;1;1];
//We specify the linear equality constraints below.
Aeq = [1/3,-5; 2, 1];
beq =  [11;8];
// Run fminimax
[x,fval,maxfval,exitflag,output,lambda] = fminimax(myfun, x0,A,b,Aeq,beq)

Authors

Animesh Baranawal

You are here

fminimax

Calling Sequence

Input Parameters

Outputs

Description

Options

Syntax

Example

Example

Example

Example

Example

Example

Example

Authors