Input Parameters

f :

A function, representing the objective function of the problem.

x0 :

A vector of doubles, containing the starting values of variables of size (1 X n) or (n X 1) where 'n' is the number of variables.

intcon :

A vector of integers, representing the variables that are constrained to be integers.

A :

A matrix of doubles, containing the coefficients of linear inequality constraints of size (m X n) where 'm' is the number of linear inequality constraints.

b :

A vector of doubles, related to 'A' and represents the linear coefficients in the linear inequality constraints of size (m X 1).

Aeq :

A matrix of doubles, containing the coefficients of linear equality constraints of size (m1 X n) where 'm1' is the number of linear equality constraints.

beq :

A vector of double, vector of doubles, related to 'Aeq' and represents the linear coefficients in the equality constraints of size (m1 X 1).

lb :

A vector of doubles, containing the lower bounds of the variables of size (1 X n) or (n X 1) where 'n' is the number of variables.

ub :

A vector of doubles, containing the upper bounds of the variables of size (1 X n) or (n X 1) where 'n' is the number of variables.

nlc :

A function, representing the nonlinear Constraints functions(both Equality and Inequality) of the problem. It is declared in such a way that nonlinear inequality constraints (c), and the nonlinear equality constraints (ceq) are defined as separate single row vectors.

options :

A list, containing the option for user to specify. See below for details.

Outputs

xopt :

A vector of doubles, containing the the computed solution of the optimization problem.

fopt :

A double, containing the value of the function at xopt.

exitflag :

An integer, containing the flag which denotes the reason for termination of algorithm. See below for details.

gradient :

a vector of doubles, containing the Objective's gradient of the solution.

hessian :

a matrix of doubles, containing the Objective's hessian of the solution.

Description

Search the minimum of a mixed integer constrained optimization problem specified by : Find the minimum of f(x) such that

intfmincon calls Bonmin, an optimization library written in C++, to solve the Constrained Optimization problem.

Options

options= list("IntegerTolerance", [---], "MaxNodes",[---], "MaxIter", [---], "AllowableGap",[---] "CpuTime", [---],"gradobj", "off", "hessian", "off" );

• IntegerTolerance : A Scalar, a number with that value of an integer is considered integer.
• MaxNodes : A Scalar, containing the maximum number of nodes that the solver should search.
• CpuTime : A scalar, specifying the maximum amount of CPU Time in seconds that the solver should take.
• AllowableGap : A scalar, that specifies the gap between the computed solution and the the objective value of the best known solution stop, at which the tree search can be stopped.
• MaxIter : A scalar, specifying the maximum number of iterations that the solver should take.
• gradobj : A string, to turn on or off the user supplied objective gradient.
• hessian : A scalar, to turn on or off the user supplied objective hessian.

options = list('integertolerance',1d-06,'maxnodes',2147483647,'cputime',1d10,'allowablegap',0,'maxiter',2147483647,'gradobj',"off",'hessian',"off")

The exitflag allows to know the status of the optimization which is given back by Ipopt.

• 0 : Optimal Solution Found
• 1 : InFeasible Solution.
• 2 : Objective Function is Continuous Unbounded.
• 3 : Limit Exceeded.
• 4 : User Interrupt.
• 5 : MINLP Error.

For more details on exitflag, see the Bonmin documentation which can be found on http://www.coin-or.org/Bonmin

Example

Here we solve a simple objective function, subjected to three linear inequality constraints.

Find x in R^2 such that it minimizes:

//Example 1:
//Objective function to be minimised
function [y, dy]=f(x)
y=-x(1)-x(2)/3;
dy= [-1,-1/3];
endfunction
//Starting point
x0=[0 , 0];
//Integer constraints
intcon = [1];
//Initializing the linear inequality constraints
A=[1,1 ; 1,1/4 ; 1,-1 ;];
b=[2;1;2];
//Calling Bonmin
[x,fval,exitflag,grad,hessian] =intfmincon(f, x0,intcon,A,b)
// Press ENTER to continue

Example

Here we build up on the previous example by adding linear equality constraints. We add the following constraints to the problem specified above:

//Example 2:
//Objective function to be minimised
function [y, dy]=f(x)
y=-x(1)-x(2)/3;
dy= [-1,-1/3];
endfunction
//Starting point
x0=[0 , 0];
//Integer constraints
intcon = [1];
//Initializing the linear inequality constraints
A=[1,1 ; 1,1/4 ; 1,-1 ;];
b=[2;1;2];
//Linear equality constraints
Aeq=[1,-1;2,1];
beq=[1,2];
//Calling Bonmin
[x,fval,exitflag,grad,hessian] =intfmincon(f, x0,intcon,A,b,Aeq,beq)
// Press ENTER to continue

Example

In this example, we proceed to add the upper and lower bounds to the objective function.

Find x in R^2 such that it minimizes:

//Example 3:
//Objective function to be minimised
function [y, dy]=f(x)
y=-x(1)-x(2)/3;
dy= [-1,-1/3];
endfunction
//Starting point
x0=[0 , 0];
//Integer constraints
intcon = [1];
//Initializing the linear inequality constraints
A=[1,1 ; 1,1/4 ; 1,-1 ;];
b=[2;1;2];
//Linear equality constraints
Aeq=[1,-1;2,1];
beq=[1,2];
//Adding the variable bounds  
lb=[-1, -%inf];
ub=[%inf, 1];
//Calling Bonmin
[x,fval,exitflag,grad,hessian] =intfmincon(f, x0,intcon,A,b,Aeq,beq,lb,ub)
// Press ENTER to continue

Example

Finally, we add the nonlinear constraints to the problem. Note that there is a notable difference in the way this is done as compared to defining the linear constraints.

//Example 4:
//Objective function to be minimised
function [y, dy]=f(x)
y=x(1)*x(2)+x(2)*x(3);
dy= [x(2),x(1)+x(3),x(2)];
endfunction
//Starting point, linear constraints and variable bounds
x0=[0.1 , 0.1 , 0.1];
intcon = [2]
A=[];
b=[];
Aeq=[];
beq=[];
lb=[];
ub=[];
//Nonlinear constraints
function [c, ceq, cg, cgeq]=nlc(x)
c = [x(1)^2 - x(2)^2 + x(3)^2 - 2 , x(1)^2 + x(2)^2 + x(3)^2 - 10];
ceq = [];
cg=[2*x(1) , -2*x(2) , 2*x(3) ; 2*x(1) , 2*x(2) , 2*x(3)];
cgeq=[];
endfunction
//Options
options=list("MaxIter", [1500], "CpuTime", [500], "GradObj", "on","GradCon", "on");
//Calling Ipopt
[x,fval,exitflag,output] =intfmincon(f, x0,intcon,A,b,Aeq,beq,lb,ub,nlc,options)
// Press ENTER to continue

Example

We can further enhance the functionality of intfmincon by setting input options. We can pre-define the gradient of the objective function and/or the hessian of the lagrange function and thereby improve the speed of computation. This is elaborated on in example 5. We take the following problem and add simple nonlinear constraints, specify the gradients and the hessian of the Lagrange Function. We also set solver parameters using the options.

//Example 5:
//Objective function to be minimised
function [y, dy]=f(x)
y=x(1)*x(2)+x(2)*x(3);
dy= [x(2),x(1)+x(3),x(2)];
endfunction
//Starting point, linear constraints and variable bounds
x0=[0.1 , 0.1 , 0.1];
intcon = [2]
A=[];
b=[];
Aeq=[];
beq=[];
lb=[];
ub=[];
//Nonlinear constraints
function [c, ceq, cg, cgeq]=nlc(x)
c = [x(1)^2 - x(2)^2 + x(3)^2 - 2 , x(1)^2 + x(2)^2 + x(3)^2 - 10];
ceq = [];
cg=[2*x(1) , -2*x(2) , 2*x(3) ; 2*x(1) , 2*x(2) , 2*x(3)];
cgeq=[];
endfunction
//Options
options=list("MaxIter", [1500], "CpuTime", [500], "GradObj", "on","GradCon", "on");
//Calling Ipopt
[x,fval,exitflag,output] =intfmincon(f, x0,intcon,A,b,Aeq,beq,lb,ub,nlc,options)
// Press ENTER to continue

Example

Infeasible Problems: Find x in R^3 such that it minimizes:

//Example 6:
//Objective function to be minimised
function [y, dy]=f(x)
y=x(1)*x(2)+x(2)*x(3);
dy= [x(2),x(1)+x(3),x(2)];
endfunction
//Starting point, linear constraints and variable bounds
x0=[1,1,1];
intcon = [2]
A=[];
b=[];
Aeq=[];
beq=[];
lb=[0 0.2,-%inf];
ub=[0.6 %inf,1];
//Nonlinear constraints
function [c, ceq, cg, cgeq]=nlc(x)
c=[x(1)^2-1,x(1)^2+x(2)^2-1,x(3)^2-1];
ceq=[x(1)^3-0.5,x(2)^2+x(3)^2-0.75];
cg = [2*x(1),0,0;2*x(1),2*x(2),0;0,0,2*x(3)];
cgeq = [3*x(1)^2,0,0;0,2*x(2),2*x(3)];
endfunction
//Options
options=list("MaxIter", [1500], "CpuTime", [500], "GradObj", "on","GradCon", "on");
//Calling Bonmin
[x,fval,exitflag,grad,hessian] =intfmincon(f, x0,intcon,A,b,Aeq,beq,lb,ub,nlc,options)
// Press ENTER to continue

Example

Unbounded Problems: Find x in R^3 such that it minimizes:

//Example 7:
//The below problem is an unbounded problem:
//Find x in R^3 such that it minimizes:
//f(x)= -(x1^2 + x2^2 + x3^2)
//x0=[0.1 , 0.1 , 0.1]
//  x1 <= 0
//  x2 <= 0
//  x3 <= 0
//Objective function to be minimised
function y=f(x)
y=-(x(1)^2+x(2)^2+x(3)^2);
endfunction
//Starting point, linear constraints and variable bounds
x0=[0.1 , 0.1 , 0.1];
intcon = [3]
A=[];
b=[];
Aeq=[];
beq=[];
lb=[];
ub=[0,0,0];
//Options
options=list("MaxIter", [1500], "CpuTime", [500]);
//Calling Bonmin
[x,fval,exitflag,grad,hessian] =intfmincon(f, x0,intcon,A,b,Aeq,beq,lb,ub,[],options)
// Press ENTER to continue

Authors

• Harpreet Singh